________________________________________________________________________________
Inhalt....: Visualisierung der Binomialverteilung
Kategorie.: Arbeitsblatt
Mathematik: Stochastik, Statistik, Programmierung
MuPAD.....: 3.0.0
Datum.....: 2005-12-20
Autoren...: Kai Gehrs <gehrs@mupad.de>
Funktionen: stats::binomialPF, stats::binomialCDF, if, elif, else,
Funktionen: plot::Rectangle, plot::Function2d, XAxisTitle, YAxisTitle, Header
________________________________________________________________________________
Visualisierung der Binomialverteilung
In diesem Arbeitsblatt stellen wir eine Prozedur zur Verfügung, mit deren
Hilfe sich Binomialverteilungen visualsieren und zusätzlich die entsprechen-
den Wahrscheinlichkeiten berechnen lassen.
Die folgende Prozedur BinomialV kann mit 3 oder 4 Argumenten aufgerufen
werden:
erstes Argument - n
bezeichnet die Anzahl der unabhängigen Wiederholungen
des Bernoulli-Experiments
zweites Argument - p
bezeichnet die Trefferwahrscheinlichkeit oder auch Erfolgs-
wahrscheinlichkeit des Bernoulli-Experiments
drittes Argument - Bereich
bezeichnet die Spanne für die entsprechende binomial-
verteilte Zufallsgröße mit Parametern n und p, für die
die Wahrscheinlichkeit betrachtet werden soll
Formal: Ist X eine binomialverteilte Zufallsgröße mit
Parametern n und p, so werden die Werte
Bereich[1] <= X <= Bereich[2]
betrachtet
viertes Argument - opt (optional)
unterscheidet zwischen der gewählten Art der Visualisierung.
opt = Graph
grafische Darstellung der Binomialverteilung über
Säulendiagramme, wobei diejenigen Säulen, die
sich in dem angegebenen Bereich befinden, extra
eingefärbt werden
opt = Glocke
grafische Darstellung der Binomialverteilung über
Säulendiagramme, wobei diejenigen Säulen, die
sich in dem angegebenen Bereich befinden, extra
eingefärbt werden und zusätzlich die zugehörige
Gauß-Glocke mit eingezeichnet wird
Wird die Prozedur nur mit 3 Argumenten aufgerufen, so wird die
Wahrscheinlichkeit P(Bereich[1] <= X <= Bereich[2]) für eine mit
den Parametern n und p binomialverteilte Zufallsgröße X ausge-
geben.
BinomialV:= proc(n, p, Bereich, opt)
local i, pf, cdf;
begin
if args(0) = 4 and opt = Graph then
pf:= stats::binomialPF(n,p):
plot( plot::Rectangle(i-0.5..i+0.5, 0..pf(i),
FillColor = RGB::Red,
Filled)
$ i = 0..n,
plot::Rectangle(i-0.5..i+0.5, 0..pf(i),
FillColor = RGB::Red,
Filled, FillPattern = Solid)
$ i = Bereich,
XAxisTitle = "k", YAxisTitle = "B(n,p,k)",
Header = "Binomialverteilung"
)
elif args(0) = 4 and opt = Glocke then
pf:= stats::binomialPF(n,p):
plot( plot::Rectangle(i-0.5..i+0.5, 0..pf(i),
FillColor = RGB::Red,
Filled)
$ i = 0..n,
plot::Rectangle(i-0.5..i+0.5, 0..pf(i),
FillColor = RGB::Red,
Filled, FillPattern = Solid)
$ i = Bereich,
XAxisTitle = "k", YAxisTitle = "B(n,p,k)",
plot::Function2d(1/sqrt(n*p*(1-p)) * 1/sqrt(2*PI) *
exp(-(x-n*p)^2/(2*n*p*(1-p))),
x = -0.5..n, LineWidth = 0.5),
Header = "Binomialverteilung mit Gauss-Glocke"
)
else
cdf:= stats::binomialCDF(n,p):
return(cdf(Bereich[2]) - cdf(Bereich[1]-1))
end_if;
end_proc:
Wir wählen im folgenden die Parameter n = 20 und p = 3/4.
n:= 20: p:= 3/4:
Ist X eine binomialverteilte Zufallsgröße zu diesen Parameterwerten, so ist die
Wahrscheinlichkeit, dass X Werte aus dem Bereich von 16 bis 18 annimmt,
gegeben durch:
BinomialV(n, p, 16..18)
Näherungsweise ergibt das:
float(BinomialV(n, p, 16..18))
Die zu der Wahrscheinlichkeit gehörige Fläche, die sich ergibt, wenn man die
gesamte Binomialverteilung zu den gewählten Werten für n und p in Form eines
Säulendiagramms darstellt, ergibt sich zu:
BinomialV(n, p, 16..18, Graph)
Zusätzlich kann die zugehörige Gauß-Glocke mit eingezeichnet werden:
BinomialV(n, p, 16..18, Glocke)
_______________________________________________________________________________
Anmerkungen:
1. Weitere Anregungen finden Sie in der Buchreihe Mathematik 1 x anders. In dieser Reihe
wird eine Vielzahl unterschiedlichster mathematischer Probleme mit MuPAD gelöst. Die
Bücher können unter www.schule.mupad.de/literatur kostenfrei kopiert werden.
_______________________________________________________________________________