________________________________________________________________________________
Inhalt....: Ausbreitung zweier Kreiswellen (Animation)
Kategorie.: Unterrichtsmaterial
Mathematik: Physik
MuPAD.....: 3.1.0
Datum.....: 2004-11-29
Autoren...: Gert Kleinstück <gert.kleinstueck1@lspb.de>
Funktionen: ->, plot::Function2d, plot::Point2d, LineStyle, AxesTitles
Funktionen: YAxisTitleOrientation, plot::Circle2d, Legend,
________________________________________________________________________________
Überlagerung von Kreiswellensystemen
In diesem Arbeitsblatt werden anmiert dargestellt
- die Wellenfronten von Kreiswellen, die von zwei Zentren ausgehen
- ihre Überlagerung in einem frei wählbaren Punkt der Ebene in Abhängigkeit von der Zeit.
Die Ausbreitung wird dargestellt in einem Koordinatensystem, in dem sich die
Wellenzentren in den Punkten Z1 (-d I 0) und Z2 (d I 0) befinden.
Es wird angenommen, dass die Ausbreitungsgeschwindigkeit c konstant ist.
Zunächst werden vorgegeben
- der Abstand d der Wellenzentren vom Ursprung
- die Wellenlänge L .
d:=4 :
L:=2 :
Es werden animiert jeweils imax Wellenfronten gezeichnet, die sich von den
Wellenzentren ausgehend ausbreiten.
Dabei markieren benachbarte Kreislinien (jeweils gestrichelt und durchgezogen)
Wellenfronten mit gegenphasigem Schwingungszustand.
imax := 5:
for i from 1 to imax do
kl1[i] := plot::Circle2d(a-(L/2)*2*(i-1), [-d,0],
a = 0..L*imax,
Color = RGB::Blue);
kl2[i] := plot::Circle2d(a-(L/2)*(2*i-1), [-d,0],
a = 0..L*imax,
Color = RGB::Blue,
LineStyle = Dashed);
kr1[i] := plot::Circle2d(a-(L/2)*2*(i-1), [d,0],
a = 0..L*imax,
Color=RGB::CornflowerBlue);
kr2[i] := plot::Circle2d(a-(L/2)*(2*i-1),[d,0],
a = 0..L*imax,
Color = RGB::CornflowerBlue,
LineStyle = Dashed);
end_for:
KW:=plot::Scene2d(kl1[i] $ i=1..imax, kl2[i] $ i=1..imax,
kr1[i] $ i=1..imax, kr2[i] $ i=1..imax):
plot(KW, Width = 160, Height = 100):
Betrachtet wird nun ein Körper im Punkt P (p1Ip2) der Ebene,
der von den Wellenfronten erfasst wird.
Für diesen werden zunächst die Abstände d1 und d2 von den
Wellenzentren berechnet.
p1:=1: p2:=2:
d1:=sqrt(p2^2+(p1+d)^2):
d2:=sqrt(p2^2+(p1-d)^2):
//Alternativ können diese auch direkt vorgegeben werden, z.B. als
Vielfache der Wellenlänge. Aus diesen werden dann die Koordinaten
des Punktes P in der oberen Halbebene berechnet.
//d1:=1.5*L: d2:=2*L:
//p1:=(d1^2-d2^2)/(4*d):
//p2:=sqrt(d1^2-(p1+d)^2):
P := plot::Point2d(p1,p2, PointSize=1.5*unit::mm, Title="P", TitlePosition=[p1,p2+1]):
Im folgenden wird idealerweise angenommen, dass
- in den Zentren gleichphasig Schwingungen gleicher Amplitude und
Schwingungsdauer einsetzen, die sich durch s(t)=1*sin(2*PI*t/T)
beschreiben lassen
- die Amplituden bei der Ausbreitung konstant bleiben.
Nach Festlegung der Periodendauer T werden nun ergänzend die Elongationen
f1 und f2 dargestellt, die von den beiden Kreiswellen einzeln hervorgerufen
würden, sowie die sich ergebende Überlagerung.
T:=3: c:=L/T:
f1 := t->piecewise([t<d1/c,0],
[d1/c<=t<=x/c,sin(2*PI*(t/T-d1/L))],
[t>x/c,0]):
f2 := t->piecewise([t<d2/c,0],
[d2/c<=t<=x/c,sin(2*PI*(t/T-d2/L))],
[t>x/c,0]):
fs:=f1+f2:
F1 := plot::Function2d(f1, t = 0..imax*T, x = 0..imax*L,
Legend = "von links kommende Welle f1",
Color = RGB::Blue):
F2 := plot::Function2d(f2, t = 0..imax*T, x = 0..imax*L,
Legend = "von rechts kommende Welle f2",
Color = RGB::CornflowerBlue):
Fs := plot::Function2d(fs, t = 0..imax*T, x = 0..imax*L,
Legend = "Überlagerung von f1 und f2",
Color = RGB::Red):
F := plot::Scene2d(F1,F2,Fs,
AxesTitles=["Zeit t","Elongation im Punkt P"],
YAxisTitleOrientation = Vertical):
Zusätzlich zu den Einzelschwingungen und der Gesamtschwingung können
noch einmal die Kreiswellensysteme und der gewählte Punkt dargestellt werden.
KWP := plot::Scene2d(kl1[i] $ i=1..imax, kl2[i] $ i=1..imax,
kr1[i] $ i=1..imax, kr2[i] $ i=1..imax,
P):
plot(KWP, F,
Header = "Überlagerung von Kreiswellensystemen",
BorderWidth = 1,
Rows = 2,
Width = 160,
Height = 140 )
_______________________________________________________________________________
Anmerkungen:
1. Weitere Anregungen finden Sie in der Buchreihe Mathematik 1 x anders. In dieser Reihe
wird eine Vielzahl unterschiedlichster mathematischer Probleme mit MuPAD gelöst. Die
Bücher können unter www.schule.mupad.de/literatur kostenfrei kopiert werden.
_______________________________________________________________________________