________________________________________________________________________________
Inhalt....: Hypothesentest, rechtsseitig, allgemein
Kategorie.: Unterrichtsmaterial
Mathematik: Stochastik
MuPAD.....: 3.1.0
Datum.....: 2005-04-04
Autoren...: Achim Burgermeister <a.burgermeister@web.de>
Funktionen: proc, while, binomial, print, Unquoted, _plus
Funktionen: stats::binomialPF, stats::binomialCDF, plot::Bars2d
________________________________________________________________________________
Hypothesentest:
Signifikanzniveau (alpha), Annahmebereich (0..Grenze), oder Ablehnungsbereich (Grenze+1..N)
nennt man rechtsseitigen Test. Der Ablehnungsbereich ist rechts.
Eine Sendung wird abgelehnt, wenn die Anzahl aus der Stichprobe im Ablehnungsbereich liegt.
Für einen Signifikanztest muss der Ablehnungsbereich so gewählt werden, dass die
Wahrscheinlichkeit dafür kleiner oder gleich 5 % ist, dann nennt man den Test signifikant, bei
der Wahrscheinlichkeit kleiner oder gleich 1 % nennt man den Test hoch signifikant.
Wir versuchen die Grenze für diesen Ablehnungsbereich mit Signifikanz Alpha zu finden:
Die Wahrscheinlichkeit die richtige Nullhypothese abzulehnen bezeichnet man mit
Fehler 1.Art = alpha.
Einseitiger rechtsseitiger Signifikanztest
-------------------------------------------------------------------------------------------------
1. Fall Signifikanzniveau ist gegeben,
Grenze ist gesucht
Eingabe:
n = Gesamtzahl in der Stichprobe
p = Wahrscheinlichkeit
alpha = Signifikanzniveau
n:= 100:
p:= 0.3:
alpha:= 0.05:
hold(n) = n, hold(p) = p, hold(alpha) = alpha
Die Verteilungsfunktion:
DIGITS:= 7:
B3:= stats::binomialCDF(n,p):
float(B3(x)) $ x = 0..n:
Zeichnen der Binomialverteilung:
B:= (n, p, k) -> binomial(n,k) * p^k * (1-p)^(n-k)
plot(plot::Bars2d([float(B(n,p,k)) $ k = 0..n], BarStyle = Lines)):
Prozedur, um die Grenze für alpha zu finden:
Loesung:= proc(a)
begin
i:=n:
while 1-B3(i) <= a do
i:=i-1;
end_while;
return(i+1);
end_proc:
DIGITS:= 3:
Grenze:= Loesung(alpha):
a:= float(1-B3(Grenze)):
b:= 100*float(a):
print(Unquoted,
"Grenze des Annahmebereichs= ".expr2text(Grenze).
", \nSignifikanzniveau alpha mit real: ".expr2text(a).
" oder ".expr2text(b)."%".
"\nAnnahmebereich= [0 bis ".expr2text(Grenze).
"], \nAblehnungsbereich = [".expr2text(Grenze+1).
" bis ".expr2text(n)."]"):
Grenze des Annahmebereichs= 38,
Signifikanzniveau alpha mit real: 0.034 oder 3.4%
Annahmebereich= [0 bis 38],
Ablehnungsbereich = [39 bis 100]
GrenzeP:= plot::Line2d([Grenze + 0.5, 0],
[Grenze + 0.5, float(B(n,p,Grenze)*1.5)],
LineColor = RGB::Red,
LineWidth = 0.7,
LineStyle = Solid):
plot(GrenzeP,
plot::Bars2d([float(B(n,p,k)) $ k = 0..Grenze],
BarStyle = Boxes,
Color = RGB::Blue,
FillPatterns = XCrossedLines),
plot::Bars2d([0 $ Grenze+1,float(B(n,p,k)) $ k = Grenze+1..n],
BarStyle = Boxes,
Color = RGB::Red,
FillPatterns = DiagonalLines,
GridVisible = TRUE)):
--------------------------------------------------------------------------------------------------
2. Fall Grenze ist gegeben,
Alpha gesucht
Eingabe:
n = Anzahl der Stichprobe
p = Wahrscheinlichkeit
Grenze = Grenze des Annahmebereichs
n:= 200:
p:= 0.04:
Grenze:= 13:
hold(n) = n, hold(p) = p, hold(Grenze) = Grenze
Verteilungsfunktion:
DIGITS:= 5:
B3:= stats::binomialCDF(n,p):
float(B3(x)) $ x = 0..n:
print(Unquoted,"Alpha für Ablehnungsbereich= ".
expr2text(round(float(1-B3(Grenze))*10e5)/10e5)." oder ".
expr2text(float(1-B3(Grenze))*100)."%".
"\nAnnahmebereich= [0 bis ".expr2text(Grenze).
"], \nAblehnungsbereich= [".expr2text(Grenze+1).
" bis ".expr2text(n)."]"):
Alpha für Ablehnungsbereich= 0.031212 oder 3.1212%
Annahmebereich= [0 bis 13],
Ablehnungsbereich= [14 bis 200]
Zeichnen der Binomialverteilung mit Grenze:
GrenzeP:= plot::Line2d([Grenze + 0.5,0],
[Grenze + 0.5, float(B(n,p,Grenze)*1.5)],
LineColor = RGB::Red,
LineWidth = 0.7,
LineStyle = Solid):
plot(GrenzeP,
plot::Bars2d([float(B(n,p,k)) $ k = 0..Grenze],
BarStyle = Boxes,
Color = RGB::Blue,
FillPatterns = XCrossedLines),
plot::Bars2d([0 $ Grenze+1,float(B(n,p,k)) $ k = Grenze+1..n],
BarStyle = Boxes,
Color = RGB::Red,
FillPatterns = DiagonalLines,
GridVisible = TRUE)): //Lines
________________________________________________________________________________
Anmerkungen:
1. Weitere Anregungen zum Einsatz von MuPAD in der Lehre finden Sie auf unserem WebPortal
MuPAD in Schule und Studium unter: http://schule.mupad.de bzw. http://studium.mupad.de.
________________________________________________________________________________